From 8353554315564b89dfe27d5130080ed04a0a65ad Mon Sep 17 00:00:00 2001
From: Linnnus <linnnus@users.noreply.github.com>
Date: Sat, 21 Dec 2024 15:47:33 +0100
Subject: Move to a profile-based configuration where common

This patch makes it so common configuration is now located in shared/
and each host basically just becomes a bunch of import statements.

The exception here is host-specific configuration like the `*.linus.onl`
that live inside `hosts/ahmed/`.

Specifically I have:

- moved common configuration `shared/{nixos,home-manager,nix-darwin}`.
- moved `hosts/common.nix` to `shared/nixos/common-{nix,shell}-settings.nix`.
- split `hosts/muhammed/{dev-utils,neovim}` into per-language
  configuration.

This patch was done in preparation for the arrival of a new host, which
will need to share a lot of configuration with Muhammed.
---
 shared/home-manager/git/ignore.nix | 37 +++++++++++++++++++++++++++++++++++++
 1 file changed, 37 insertions(+)
 create mode 100644 shared/home-manager/git/ignore.nix

(limited to 'shared/home-manager/git/ignore.nix')

diff --git a/shared/home-manager/git/ignore.nix b/shared/home-manager/git/ignore.nix
new file mode 100644
index 0000000..8d1da2f
--- /dev/null
+++ b/shared/home-manager/git/ignore.nix
@@ -0,0 +1,37 @@
+# This module defines the contents of `~/.config/git/ignore`. It fetches the
+# templates for different gitignores and compiles them into one.
+{
+  pkgs,
+  lib,
+  ...
+}: let
+  gitignore = ignores:
+    pkgs.stdenv.mkDerivation {
+      name = (lib.concatStringsSep "+" ignores) + ".gitignore";
+
+      src = pkgs.fetchFromGitHub {
+        owner = "toptal";
+        repo = "gitignore";
+        rev = "7e72ecd8af69b39c25aedc645117f0dc261cedfd";
+        hash = "sha256-Ln3w6wx+pX4UFLY2gGJGax2/nxgp/Svrn0uctSIRdEc=";
+      };
+
+      inherit ignores;
+      buildPhase = ''
+        for i in $ignores; do
+          cat ./templates/$i.gitignore >>$out
+        done
+      '';
+    };
+
+  targets =
+    [
+      "Node"
+      "Deno"
+      "C"
+    ]
+    ++ (lib.optional pkgs.stdenv.isDarwin "MacOS")
+    ++ (lib.optional pkgs.stdenv.isLinux "Linux");
+in {
+  xdg.configFile."git/ignore".source = gitignore targets;
+}
-- 
cgit v1.2.3