hosts/muhammed/configuration.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74

# This file contains the configuration for my Macbook Pro.
{
  flakeInputs,
  pkgs,
  lib,
  ...
}: {
  imports = [
    ../../shared/nixos/common-shell-settings
    ../../shared/nixos/common-nix-settings
    ../../shared/nixos/common-hm-settings

    ./remote-builders
  ];

  # Specify the location of this configuration file. Very meta.
  environment.darwinConfig = flakeInputs.self + "/hosts/muhammed/configuration.nix";

  # Avoid downloading the nixpkgs tarball every hour.
  # See: https://cohost.org/fullmoon/post/1728807-nix-s-tarball-ttl-op
  nix.settings.tarball-ttl = 604800;

  # Use the Nix daemon.
  services.nix-daemon.enable = true;

  # Set up main account.
  users.users.linus = {
    description = "Personal user account";
    home = "/Users/linus";
  };

  home-manager.users.linus = {
    imports = [
      ../../shared/home-manager/development-full
      ../../shared/home-manager/qbittorrent
      ../../shared/home-manager/iterm2
      ({pkgs, ...}: {
        home.packages = with pkgs; [
          imagemagick
          ffmpeg_6-full
        ];
      })
    ];
  };

  # Should match containing folder.
  networking.hostName = "muhammed";

  # Let's use fingerprint to authenticate sudo. Very useful as an indicator of
  # when darwin-rebuild is finished...
  security.pam.enableSudoTouchIdAuth = true;

  # Don't request password for running pmset.
  environment.etc."sudoers.d/10-unauthenticated-commands".text = let
    commands = [
      "/usr/bin/pmset"
      (lib.getExe pkgs.disable-sleep)
    ];
  in ''
    %admin ALL=(ALL:ALL) NOPASSWD: ${builtins.concatStringsSep ", " commands}
  '';

  services.still-awake.enable = true;

  # Enable nightly GC of Nix store.
  nix.gc = {
    automatic = true;
    interval = {Hour = 3;};
  };

  # System-specific version info.
  home-manager.users.linus.home.stateVersion = "22.05";
  system.stateVersion = 4;
}