blob: 401d4a5887ad872296f1bed55d1da8eaf83879bd (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
{ pkgs, config, lib, ... }:
with lib;
let
cfg = config.my.secrets;
secret = types.submodule {
options = {
source = mkOption {
type = types.path;
description = "local secret path";
};
dest = mkOption {
type = types.str;
description = "where to write the decrypted secret to";
};
owner = mkOption {
default = "root";
type = types.str;
description = "who should own the secret";
};
group = mkOption {
default = "root";
type = types.str;
description = "what group should own the secret";
};
permissions = mkOption {
default = "0400";
type = types.str;
description = "Permissions expressed as octal.";
};
};
};
metadata = lib.importTOML ./metadata.toml;
mkSecretOnDisk = name:
{ source, ... }:
pkgs.stdenv.mkDerivation {
name = "${name}-secret";
phases = "installPhase";
buildInputs = [ pkgs.rage ];
installPhase =
let
key = metadata.hosts."${config.networking.hostName}".sshPubKey;
in
''
rage -a -r '${key}' -o "$out" '${source}'
'';
};
mkService = name:
{ source, dest, owner, group, permissions, ... }: {
description = "decrypt secret for ${name}";
wantedBy = [ "multi-user.target" ];
serviceConfig.Type = "oneshot";
script = with pkgs; ''
rm -rf ${dest}
"${rage}"/bin/rage -d -i /etc/ssh/ssh_host_ed25519_key -o '${dest}' '${
mkSecretOnDisk name { inherit source; }
}'
chown '${owner}':'${group}' '${dest}'
chmod '${permissions}' '${dest}'
'';
};
in
{
options.my.secrets = mkOption {
type = types.attrsOf secret;
description = "secret configuration";
default = { };
};
config.systemd.services =
let
units = mapAttrs'
(name: info: {
name = "${name}-key";
value = (mkService name info);
})
cfg;
in
units;
}
|
